feat: added phong and basic shaders, updated mesh format

assets/shaders/phong-solid.fragment.glsl

@@ -0,0 +1,35 @@
+#version 330 core
+out vec4 frag_color;
+
+uniform vec3 light_pos;
+uniform vec3 solid_color;
+
+in vec3 normal_cameraspace;
+in vec3 light_direction_cameraspace;
+in vec3 eye_direction_cameraspace;
+in vec3 position_worldspace;
+
+void main() {
+    vec4 material_diffuse_color = vec4(solid_color, 1); 
+    vec4 material_ambient_color = vec4(0.1, 0.1, 0.1, 1.0) * material_diffuse_color;
+    vec4 material_specular_color = vec4(1.0, 1.0, 1.0, 1.0); 
+
+    vec3 normal = normalize(normal_cameraspace);
+    vec3 light_dir = normalize(light_direction_cameraspace);
+    float cos_theta = clamp(dot(normal, light_dir), 0, 1);
+
+    vec3 eye = normalize(eye_direction_cameraspace);
+    vec3 reflected = reflect(-light_dir, normal);
+    float cos_alpha = clamp(dot(eye, reflected), 0, 1);
+
+    vec4 light_color = vec4(1, 1, 1, 1);
+    float light_power = 60;
+
+    float distance = length(light_pos - position_worldspace);
+    float dist_sq = pow(distance, 2);
+
+    vec4 diffuse = material_diffuse_color * light_color * light_power * cos_theta / dist_sq;
+    vec4 specular = material_specular_color * light_color * light_power * pow(cos_alpha, 10) / dist_sq;
+
+    frag_color = material_ambient_color + diffuse + specular; 
+};